7 img_plot.menu  JJK RMMC  03/31/98

                 IMAGE  PLOTTING  MENU
  NOTE: If an image does not appear in the list below,
        it may be missing a corresponding header file
        (.hdr for BIL, BIP, BSQ; or .tfw for TIFF).
        Use the DOQHEAD toolkit to create a ".hdr" file
        for BIL/BIP DOQ images.  Manually create a 
        ".tfw" file for TIFF images.  See img_plot.aml
        header for useable dummy header file examples.

 1. Click on Image:
        %image







 2. Extent to plot:           %extent

 3. Output Plotfile Name:     %pltname
 4. Page Size (inches, X Y):  %x %y
 5. Plotfile Format:          %format

           %ok        %def          %can

/*
%image   INPUT .i_image 45 TYPEIN YES SCROLL YES ROWS 6 KEEP ~
  RETURN '&if [UPCASE %.i_extent%] = FULL &then; ~
  &s .i_plotfile = [ENTRYNAME %.i_image% -NOEXT].%.i_format%; &else; ~
  &s .i_plotfile = [ENTRYNAME %.i_image% -NOEXT]_inset.%.i_format%' ~
  REQUIRED IMAGE 
/*
%extent  CHOICE .i_extent PAIRS KEEP NEXT %pltname ~
  RETURN '&if [UPCASE %.i_extent%] = INSET &then; ~
  &s .i_msg = Select the subset extent after pressing OK; ~
  &else; &s .i_msg = The full image will be plotted; ~
  &if [UPCASE %.i_extent%] = FULL & ~
  %.i_plotfile% = [ENTRYNAME %.i_image% -NOEXT]_inset.%.i_format% &then; ~
  &s .i_plotfile = [ENTRYNAME %.i_image% -NOEXT].%.i_format%; ~
  &if [UPCASE %.i_extent%] = INSET & ~
  ( %.i_plotfile% = .%.i_format% | ~
  %.i_plotfile% = [ENTRYNAME %.i_image% -NOEXT].%.i_format% ) &then; ~
  &s .i_plotfile = [ENTRYNAME %.i_image% -NOEXT]_%.i_extent%.%.i_format%' ~
  'FULL IMAGE' 'full' 'IMAGE SUBSET' 'inset'
/*
%pltname INPUT .i_plotfile 25 TYPEIN YES SCROLL NO NEXT %x REQUIRED CHARACTER
/*
%x       INPUT .i_pgx 4 SIZE 4 TYPEIN YES SCROLL NO NEXT %y REQUIRED REAL
%y       INPUT .i_pgy 4 SIZE 4 TYPEIN YES SCROLL NO REQUIRED REAL
/*
%format  CHOICE .i_format PAIRS KEEP INITIAL gra ~
  RETURN '&s .i_plotfile = [ENTRYNAME %.i_plotfile% -NOEXT].%.i_format%' ~
  'GRA' 'gra' 'CGM' 'cgm' 'EPS' 'eps'
/*
%ok      BUTTON RETURN 'OK' &return
%def     BUTTON RETURN 'Defaults' &s .i_extent = full; &s .i_pgx = 8; ~
  &s .i_pgy = 10; &s .i_format = gra; ~
  &s .i_plotfile = [ENTRYNAME %.i_image% -NOEXT].%.i_format%; ~
  &s .i_msg = Re-setting default parameters
%can     BUTTON RETURN 'Cancel' &r img_plot cancel; &return
/*
%FORMOPT SETVARIABLES IMMEDIATE MESSAGEVARIABLE .i_msg
%FORMINIT &s .i_image = ; &s .i_pgx = 8; &s .i_pgy = 10; &s .i_format = gra; ~
  &s .i_plotfile = .%.i_format%
/*
/*
/*------------------------------------------------------------------------------
/*-----------------------------  PROGRAM  HEADER  ------------------------------
/*------------------------------------------------------------------------------
/*  Program: img_plot.menu
/*
/*  History: JKosovich  USGS  03/31/98  Original coding for Aband. Mine Lands